REM > JLibraries:Mess.2
REM © James Bursa, 1997

REM JB  16 Nov 1997     created
REM JB  17 Nov 1997     added FNMess_Global*
REM JB  06 Dec 1997     uses file pointer not names for speed


DEF FNMess_Open(Path$, Fixd%)
LOCAL Flag%, Size%, Buff%

SYS"MessageTrans_FileInfo",, Path$ TO ,, Size%
 IF Fixd% THEN
  DIM Buff% Size% + 20
  !Buff% = Buff% + 4
 ELSE
  Buff% = FNHeap_Alloc(Size% + 16)
  IF Buff% = 0 THEN ERROR Erro_Memo%, ""
 ENDIF
SYS"MessageTrans_OpenFile", !Buff%, Path$, !Buff% + 16
=Buff%

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Lookup(Tokn$, File%)
LOCAL Text$
File% = !File%
File%!8 = File% + 16
SYS"MessageTrans_Lookup", File%, Tokn$ TO ,, Text$
=Text$

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_XLookup(Tokn$, File%)
LOCAL Text$, PFlg%
File% = !File%
File%!8 = File% + 16
SYS"XMessageTrans_Lookup", File%, Tokn$ TO ,, Text$; PFlg%
IF (PFlg% AND 1) THEN =""
=Text$

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Adr(Tokn$, File%)
LOCAL Text%
File% = !File%
File%!8 = File% + 16
SYS"MessageTrans_Lookup", File%, Tokn$ TO ,, Text%
=Text%

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_XAdr(Tokn$, File%)
LOCAL Text%, PFlg%
File% = !File%
File%!8 = File% + 16
SYS"XMessageTrans_Lookup", File%, Tokn$ TO ,, Text%; PFlg%
IF (PFlg% AND 1) THEN =0
=Text%

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Get1(Tokn$, File%, a$)
=FNMess_Get4(Tokn$, File%, a$, "", "", "")

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Get2(Tokn$, File%, a$, b$)
=FNMess_Get4(Tokn$, File%, a$, b$, "", "")

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Get3(Tokn$, File%, a$, b$, c$)
=FNMess_Get4(Tokn$, File%, a$, b$, c$, "")

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Get4(Tokn$, File%, a$, b$, c$, d$)
LOCAL Text$
File% = !File%
File%!8 = File% + 16
SYS"MessageTrans_Lookup", File%, Tokn$, STRING$(255, " "), 255, a$, b$, c$, d$ TO ,, Text$
=Text$

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Global(Tokn$)
=FNMess_Global4(Tokn$, "", "", "", "")

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Global1(Tokn$, a$)
=FNMess_Global4(Tokn$, a$, "", "", "")

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Global2(Tokn$, a$, b$)
=FNMess_Global4(Tokn$, a$, b$, "", "")

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Global3(Tokn$, a$, b$, c$)
=FNMess_Global4(Tokn$, a$, b$, c$, "")

REM ˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜˜

DEF FNMess_Global4(Tokn$, a$, b$, c$, d$)
LOCAL Text$
SYS"MessageTrans_Lookup", 0, Tokn$, STRING$(255, " "), 255, a$, b$, c$, d$  TO ,, Text$
=Text$